Aktivace Windows 10, Server 2016 a Office 2016 pomocí KMS

Pomocí KMS SECO

kms seco 64bit
kms seco 32bit
Originální zdrojový kód a binárky
@echo off
Title KMS
color 1F
openfiles >NUL 2>&1
if %errorlevel% NEQ 0 goto :uac
goto :admin
:uac
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~fs0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"&del "%temp%\getadmin.vbs"&exit /b
:admin
for /f "tokens=6 delims=[]. " %%G in ('ver') do set winbuild=%%G
if %winbuild% GEQ 9600 (goto :aktivace) else (echo.&echo Pouze pro Windows 10&pause >nul&exit)

:aktivace
set kmsip=1.2.7.0
set port=1688
set hSpp="HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SoftwareProtectionPlatform"
reg delete %hSpp%\55c92734-d682-4d71-983e-d6ec3f16059f /f >nul 2>&1
reg delete %hSpp%\0ff1ce15-a989-479d-af46-f275c6370663 /f >nul 2>&1
set spp=SoftwareLicensingProduct
set sps=SoftwareLicensingService
pushd "%~dp0"
copy /y "seco\SppExtComObjPatcher.exe" "%SystemRoot%\system32" >nul 2>&1
copy /y "seco\SppExtComObjHook.dll" "%SystemRoot%\system32" >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\SppExtComObj.exe" /f /v "Debugger" /t REG_SZ /d "SppExtComObjPatcher.exe" >nul 2>&1
for /f "tokens=2 delims==" %%A in ('"wmic path %sps% get version /format:list"') do set ver=%%A
wmic path %sps% where version='%ver%' call SetKeyManagementServiceMachine "%kmsip%" >nul 2>&1
wmic path %sps% where version='%ver%' call SetKeyManagementServicePort %port% >nul 2>&1
for /f "tokens=2 delims==" %%G in ('"wmic path %spp% where ProductKeyChannel='Volume:GVLK' get ID /format:list"') do (set ID=%%G&echo.&call :ato %%G)
echo.&echo Zachovat SECO soubory v systemu [a,n]?
echo a = KMS aktivace se bude provadet automaticky.
echo n = KMS aktivace se nebude provadet automaticky.
@CHOICE /c na /n
IF %errorlevel% equ 1 GOTO k1
IF %errorlevel% equ 2 GOTO k2

:k1
taskkill /F /IM SppExtComObj.exe >nul 2>&1
del /f /q "%SystemRoot%\system32\SppExtComObjPatcher.exe" >nul 2>&1
del /f /q "%SystemRoot%\system32\SppExtComObjHook.dll" >nul 2>&1
reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\SppExtComObj.exe" /f >nul 2>&1
wmic path %sps% where version='%ver%' call ClearKeyManagementServiceMachine >nul 2>&1
wmic path %sps% where version='%ver%' call ClearKeyManagementServicePort >nul 2>&1
wmic path %sps% where version='%ver%' call DisableKeyManagementServiceDnsPublishing 1 >nul 2>&1
wmic path %sps% where version='%ver%' call DisableKeyManagementServiceHostCaching 1 >nul 2>&1
set hSpp="HKEY_USERS\S-1-5-20\Software\Microsoft\Windows NT\CurrentVersion\SoftwareProtectionPlatform"
reg delete %hSpp%\55c92734-d682-4d71-983e-d6ec3f16059f /f >nul 2>&1
reg delete %hSpp%\0ff1ce15-a989-479d-af46-f275c6370663 /f >nul 2>&1
echo Soubory SECO byly smazany.&echo.
echo Zavri okno zmacknutim libovolne klavesy.
pause >nul&exit

:k2
echo Soubory SECO byly zachovany.&echo.
echo Zavri okno zmacknutim libovolne klavesy.
pause >nul&exit

:ato
wmic path %spp% where ID='%1' call ClearKeyManagementServiceMachine >nul 2>&1
wmic path %spp% where ID='%1' call ClearKeyManagementServicePort >nul 2>&1
for /f "tokens=2 delims==" %%x in ('"wmic path %spp% where ID='%1' get Name /format:list"') do echo Aktivuji %%x
wmic path %spp% where ID='%1' call Activate >nul 2>&1
if %errorlevel% neq 0 echo Aktivace selhala&exit /b
for /f "tokens=2 delims==" %%x in ('"wmic path %spp% where ID='%1' get GracePeriodRemaining /format:list"') do (set gpr=%%x&set /a gpr2=%%x/60/24)
echo Aktivovano na %gpr2% dni (%gpr% minut)&exit /b

Pomocí virtuální diskety s KMS ve virtuálce nebo KMS ve virtuálce

vlmcsd svn1111

Aktivace 64bit Office 2016 ve Windows 10 64bit (cmd jako správce):

cscript "%ProgramFiles%\Microsoft Office\Office16\ospp.vbs" /sethst:xxx.xxx.xxx.xxx
cscript "%ProgramFiles%\Microsoft Office\Office16\ospp.vbs" /act
cscript "%ProgramFiles%\Microsoft Office\Office16\ospp.vbs" /remhst
cscript "%ProgramFiles%\Microsoft Office\Office16\ospp.vbs" /dstatus

Aktivace Windows 10 (cmd jako správce):

slmgr /skms xxx.xxx.xxx.xxx
slmgr /ato
slmgr /ckms
slmgr /dlv

Kde xxx.xxx.xxx.xxx je ip virtuálky s kms.